;
; Sintaxe
;   /GetSorte
;
; Descrição
;   Retorna a "sorte de hoje", primeiro deve-se usar o "/getOrkutCookie"
;
alias GetSorte {
  if (!%Orkut.Cookie) {
    echo -s * Cookie não encontrado, primeiro use //getOrkutCookie usuário senha
    return
  }
  unset %Orkut.Sorte
  sockopen GetSorte www.orkut.com 80
}
on *:sockopen:GetSorte:{
  var %sn = $sockname, %w = sockwrite -tn %sn
  SocketError $sockerr $event %sn
  %w GET /Home.aspx HTTP/1.1
  %w Host: www.orkut.com
  %w Accept-Charset: ISO-8859-1
  %w Cookie: orkut_state= $+ %Orkut.Cookie
  %w Connection: close
  %w
}
on *:sockread:GetSorte:{
  var %sn = $sockname, %m = $sock(%sn).mark
  SocketError $sockerr $event %sn
  sockread %a
  while ($sockbr) {

    if ( $regex(%a,/<b>Sorte\sde\shoje\s?:\s?<\/b>([^<]+)<br>/i) ) {
      set %Orkut.Sorte $remove( $regml(1), &nbsp;)
      echo -s * Sua sorte de hoje: %Orkut.Sorte
      sockclose %sn
      halt
    }
    ;Debug
    ;echo -s * %a
    sockread %a
  }
}
on *:sockclose:GetSorte:{

  if (!%Orkut.Sorte) {
    echo -s * Erro ao pegar a sua sorte de hoje. =\
  }

}

;
; Sintaxe
;   /getOrkutCookie usuário senha
;
; Descrição
;   Obtém o valor do cookie orkut_state
;
alias getOrkutCookie {
  if (!$2) { echo -s * Error: sintaxe correta /getOrkutCookie $chr(2) $+ usuario senha | return }
  if ($sock(Orkut.GET)) { echo -s * Wait: Voce ja estar realizando um processo, por favor aguarde... | return }
  unset %Orkut.*
  set %Orkut.User $replace($1,@,% $+ 40)
  set %Orkut.Pass $2
  Orkut.Open
}
alias Orkut.Open {
  var %n = Orkut.GET
  if ($sock(%n)) { sockclose %n }
  sockopen %n $+(www.,$iif($1,orkut,google),.com) 80
  sockmark %n $1
}
on *:sockopen:Orkut.GET:{
  var %sn = $sockname, %m = $sock(%sn).mark, %w = sockwrite -tn %sn
  SocketError $sockerr $event %sn
  if (%m) { %w GET /RedirLogin.aspx?auth= $+ %Orkut.Auth HTTP/1.1 | %w Host: www.orkut.com }
  else { %w GET https://www.google.com/accounts/ClientLogin?service=orkut&Email= $+ %Orkut.User $+ &Passwd= $+ %Orkut.Pass HTTP/1.1 }
  %w Connection: close
  %w
  if (%m) {
    echo -s * Recebendo o cookie...
  }
  else { echo -s * Enviando Usuario & Senha... }
}

on *:sockread:Orkut.GET:{
  var %sn = $sockname, %m = $sock(%sn).mark
  SocketError $sockerr $event %sn
  sockread %a
  while ($sockbr) {
    if (%m && $regex(%a,/^set-cookie:\sorkut_state=([^;]+)/i)) {
      unset %Orkut.*
      set %Orkut.Cookie $regml(1)
      echo -s * Cookie Pegado com sucesso. digite '//echo % $+ Orkut.Cookie' para ver seu valor.
    }
    elseif ( $regex(%a,/^auth=([^\r\n]+)/i) && !%m && $regml(1)) { set %Orkut.Auth $regml(1) | Orkut.Open 1 }
    ;Debug
    ;echo -s * %a
    sockread %a
  }
  {
    goto eof
    :error
    /reseterror
    :eof
  }

}
on *:sockclose:Orkut.GET:{
  var %m = $sock(%sn).mark
  if (%m && !%Orkut.Cookie) {
    echo -s * Ocorreu algum erro ao pegar o valor do cookie orkut_state
  }
  elseif (!%m && !%Orkut.auth && !%Orkut.Cookie) {
    echo -s * Usuário/Senha inválido, ou erro no servidor.
  }
}
alias SocketError {
  ;SocketError $sockerr $event %sn
  if ($1) {
    echo -s +ERR ( $+ $2 $+ )[ $+ $1 $+ ] em $3
    return haltdef
  }
}